Delete notes page text (or text and shapes)

If you have PowerPoint 2007 or later

• Choose Office Button | Prepare | Inspect Document
• Put a check next to Presentation Notes
• Click Inspect
• Click Remove All

Your notes are gone.

If you have an earlier version of PowerPoint

(Thanks to MVP Shyam Pillai for this one)

A VBA routine can delete all shapes from the notes page. See further on for a routine that will only delete the notes text placeholder.

Sub DelNotesShapes()
Dim oSld As Slide
For Each oSld In ActivePresentation.Slides
    If oSld.NotesPage.Shapes.Count > 0 Then
        oSld.NotesPage.Shapes.Range.Delete
    End If
Next oSld
Set oSld = Nothing
End Sub

Same strategy, slightly different approach:

Sub BlitzTheNotes()

Dim oSlides As Slides
Dim oSl As Slide
Dim x As Integer

Set oSlides = ActivePresentation.Slides
For Each oSl In oSlides
    For x = oSl.NotesPage.Shapes.Count to 1 Step -1
        oSl.NotesPage.Shapes(1).Delete
    Next x
Next oSl

End Sub

Both routines seem slightly odd, in that you'd expect to be able to do something like

For X = 1 to .Shapes.Count
    .Shapes(X).Delete
Next X

But that won't work. When you delete .Shapes(1), .Shapes(2) is now the first shape in the collection, so if you delete .Shapes(2) next, you're leaving what was 2 and is now 1 on the page. And eventually it errors because after you delete the first object of, say, 4 in the collection, there's no longer a .Shapes(4) so when you try to delete it ... BOOM!

Another approach, if you simply want to delete the notes text:

Sub BlitzTheNotesText()

    Dim oSl As Slide
    Dim oSh As Shape

    For Each oSl In ActivePresentation.Slides
        ' Locate and delete the notes page body text placeholder
        For Each oSh In oSl.NotesPage.Shapes
            If oSh.Type = msoPlaceholder Then
                ' Is the shape a body text placeholder?  If so, delete it.
                If oSh.PlaceholderFormat.Type = ppPlaceholderBody Then
                    oSh.Delete
                    ' or if you'd rather not delete the notes, use oSh.Visible = False
                    ' change it to oSh.Visible = True and rerun the macro to reverse the effect
                End If
            End If
        Next oSh
    Next oSl

End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.

---