Export Slide Number and Title Text to a text file

In mid-presentation, you can type in the number of the text you want to jump to and press Enter. Powerpoint jumps to the slide whose number you entered.

Great. Only what's the number of the slide where you discuss the newly revised petunia quotas? Who can remember?

Nobody. That's why you might want to run this little macro first. It collects the slide title and slide number from each slide in your presentation and saves it in a file you can print out. Now when somebody starts grilling you about geraniums or asking about aspidistra, you can quickly consult your list and jump right to the correct slide.

Sub GatherTitles()

On Error GoTo ErrorHandler

Dim oSlide As Slide
Dim strTitles As String
Dim strFilename As String
Dim intFileNum As Integer
Dim PathSep as String 

If ActivePresentation.Path = "" Then
    MsgBox "Please save the presentation then try again"
    Exit Sub
End If

#If Mac Then
    PathSep = ":"
#Else
    PathSep = "\"
#End If

On Error Resume Next  ' in case there's no title placeholder on the slide
For Each oSlide In ActiveWindow.Presentation.Slides
    strTitles = strTitles _
        & "Slide: " _
        & CStr(oSlide.SlideIndex) & vbCrLf _
        & oSlide.Shapes.Title.TextFrame.TextRange.Text _
        & vbCrLf & vbCrLf
Next oSlide
On Error GoTo ErrorHandler

intFileNum = FreeFile

' PC-Centricity Alert!
' This assumes that the file has a .PPT extension and strips it off to make the text file name.
strFilename = ActivePresentation.Path _
    & PathSep _
    & Mid$(ActivePresentation.Name, 1, Len(ActivePresentation.Name) - 4) _
    & "_Titles.TXT"

Open strFilename For Output As intFileNum
Print #intFileNum, strTitles

NormalExit:
Close intFileNum
Exit Sub

ErrorHandler:
MsgBox Err.Description
Resume NormalExit

End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.

Search terms:title,text,slide number,slide index,go to,extract,outline

---