Reset the size of the slide images on notes pages to a single standard size

Problem

You have a collection of slides with notes page slide images of different sizes. You'd like them all to be reset to the same size.

Solution

This macro will pick up the size of the slide image on the Notes Master and reset the size of the slide image on each of the Notes Pages to match.

Sub ResetNotesPageSlideSizes()
' resets the size of the slide placeholder on notes pages
' to the size specified in the notes master

    Dim dheight As Double
    Dim dwidth As Double
    Dim dTop As Double
    Dim dLeft As Double
    Dim oSlideShape As Shape
    Dim x As Long
    Dim oSl As Slide

    With ActivePresentation.NotesMaster
        ' Find the slide shape, get its size/position
        For x = 1 To .Shapes.Count
            If .Shapes(x).Type = msoPlaceholder Then
                Debug.Print .Shapes(x).Name & vbTab & .Shapes(x).PlaceholderFormat.Type
                If .Shapes(x).PlaceholderFormat.Type = ppPlaceholderTitle Then
                    Set oSlideShape = .Shapes(x)
                    dheight = oSlideShape.height
                    dwidth = oSlideShape.width
                    dTop = oSlideShape.Top
                    dLeft = oSlideShape.Left
                    Set oSlideShape = Nothing
                End If
            End If
        Next
    End With

    For Each oSl In ActivePresentation.Slides
        ' find the slide shape on the notes page
        With oSl
            For x = 1 To oSl.NotesPage.Shapes.Count
                If .NotesPage.Shapes(x).Type = msoPlaceholder Then
                    If .NotesPage.Shapes(x).PlaceholderFormat.Type = ppPlaceholderTitle Then
                        Set oSlideShape = .NotesPage.Shapes(x)
                        oSlideShape.height = dheight
                        oSlideShape.width = dwidth
                        oSlideShape.Top = dTop
                        oSlideShape.Left = dLeft
                        Set oSlideShape = Nothing
                    End If
                End If
            Next
        End With
    Next    ' slide

End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.

Search terms:

---