Working with Tab settings in text

Problem

You have a common set of tab stops that you'd like to apply to multiple text boxes.
Adding the tab stops manually to each text box is VERY tedious.
And that's being kind.

Solution

Select a text box that has the tab stops you want already set.
Run the GetTabStops macro below to memorize the tab settings.
Then select another text box and run SetTabStops to apply the memorized tab settings.
Then another. Click. And another. Click. This is fun! Click. And more ... Click click clickclickclick....

Option Explicit
Public atabs() As String

Sub GetTabStops()
' Select the text whose tab stops you want to pick up then run this macro

    Dim x As Long
    With ActiveWindow.Selection.ShapeRange(1)
        With .TextFrame.Ruler
            Debug.Print .TabStops.Count
            If .TabStops.Count > 0 Then
               ReDim atabs(2, 1 To .TabStops.Count) As String
               For x = 1 To .TabStops.Count
                   Debug.Print .TabStops(x).Position & vbTab & .TabStops(x).Type
                   atabs(1, x) = CStr(.TabStops(x).Position)
                   atabs(2, x) = CStr(.TabStops(x).Type)
               Next
            End If
        End With
    End With

End Sub

Sub SetTabStops()
' Run this macro to apply the memorized tab stops to the selected text

    Dim x As Long
    With ActiveWindow.Selection.ShapeRange(1)
        With .TextFrame.Ruler
            For x = 1 To .TabStops.Count
                .TabStops(x).Clear
            Next
            For x = 1 To UBound(atabs, 2)
                .TabStops.Add Type:=CLng(atabs(2, x)), Position:=CDbl(atabs(1, x))
            Next
        End With
    End With
End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.

---