Correct the order of shapes on Notes Pages. Fix disappearing notes in presenter view.

Problem

Your slide notes text doesn't appear in presenter view.

Presenter view locates the second shape on your notes pages and assumes it's the notes text placeholder.
Usually this is true but not always. If the notes text isn't the second shape on the notes page, presenter view won't display your notes text.
If the second shape on the notes page happens to have text, presenter view will display that instead of the notes text.

Solution

Run this macro on your presentation. It will move the notes page slide image and notes text placeholders into the proper order.

Sub FixNotesPageShapeOrder()

    Dim oSl As Slide
    Dim oSh As Shape

    For Each oSl In ActivePresentation.Slides
        ' Send body text to back first
        Set oSh = NotesBodyPlaceholder(oSl)
        If Not oSh Is Nothing Then
            oSh.ZOrder (msoSendToBack)
        End If
        ' Then slide image so
        Set oSh = NotesSlidePlaceholder(oSl)
        If Not oSh Is Nothing Then
            oSh.ZOrder (msoSendToBack)
        End If
        ' and now the order is Slide Image, Body Text, Otherstuff
    Next

End Sub

Function NotesBodyPlaceholder(oSl As Slide) As Shape
    Dim oSh As Shape
    For Each oSh In oSl.NotesPage.Shapes
        If oSh.Type = msoPlaceholder Then
            If oSh.PlaceholderFormat.Type = ppPlaceholderBody Then
                ' Found it!
                Set NotesBodyPlaceholder = oSh
            End If
        End If
    Next
End Function

Function NotesSlidePlaceholder(oSl As Slide) As Shape
    Dim oSh As Shape
    For Each oSh In oSl.NotesPage.Shapes
        If oSh.Type = msoPlaceholder Then
            If oSh.PlaceholderFormat.Type = ppPlaceholderTitle Then
                ' Found it!
                Set NotesSlidePlaceholder = oSh
            End If
        End If
    Next

End Function

See How do I use VBA code in PowerPoint? to learn how to use this example code.

---