Rotate an image on every other slide

Problem

A visitor to the PowerPoint Newsgroup asked if it was possible to rotate every other page in a PowerPoint presentation 180 degrees so that when printed in book form, all of the images would be facing the same way.

Solution

One approach to solving this is to export each slide in the presentation as an image, re-import each image onto a new slide in a new blank presentation, then run this macro on it to "flip" all of the images on even numbered slides.

If you want to save some time, the PPTools Protect add-in
automatically exports and imports the images for you. All you'd need to do is run it on your presentation then run the macro on the result.

Sub SpinEm()
    Dim oSl As Slide
    Dim oSh As Shape

    For Each oSl In ActivePresentation.Slides
        If IsEven(oSl.SlideIndex) Then
            Set oSh = FirstImage(oSl)
            If Not oSh Is Nothing Then
                oSh.IncrementRotation 180
            End If
        End If
    Next
End Sub

Function IsEven(lInput As Long) As Boolean
    If lInput / 2 = lInput \ 2 Then
        IsEven = True
    Else
        IsEven = False
    End If
End Function

Function FirstImage(oSl As Slide) As Shape
    Dim oSh As Shape
    For Each oSh In oSl.Shapes
        If oSh.Type = msoPicture Then
            Set FirstImage = oSh
            Exit Function
        End If
    Next

End Function

---