Show me the fonts my presentation needs

Problem

You open a presentation and it behaves oddly. Lines don't break where they should, text doesn't line up correctly and you wonder why ANYONE would have chosen THAT font.

When a presentation needs a font that's not installed on your computer, PowerPoint must substitute a different font. Sometimes it makes a pretty good guess but at other times the closest available font may be a poor substitute.

At other times, you may want to know whether PowerPoint is using fonts from your own computer or fonts that are embedded in the presentation itself.

Here's a bit of VBA you can run to learn what fonts are used in the presentation and whether or not the fonts are embedded. Or if they CAN be embedded, in case you need to send the presentation to someone else and want to make sure that they don't have font substitution.

Show Me the Fonts!

Sub ShowMeTheFonts()

    Dim x As Long
    Dim sMsg As String

    With ActivePresentation

        For x = 1 To .Fonts.Count
            With .Fonts(x)

                ' save the name of the font
                sMsg = sMsg & .Name & vbCrLf

                ' Save embeddability information:
                If .Embeddable Then
                    sMsg = sMsg & vbTab _
                        & "Embeddable" & vbCrLf
                    If .Embedded Then
                        sMsg = sMsg & vbTab _
                            & "Embedded" & vbCrLf
                    Else
                        sMsg = sMsg & vbTab _
                            & "but NOT Embedded" & vbCrLf
                    End If
                Else
                    sMsg = sMsg & vbTab _
                        & "NOT embeddable" & vbCrLf
                End If

            End With   ' Font(x)
        Next     ' Font
    End With     ' The presentation

    ' Now show us what we found
    MsgBox sMsg

End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.

---