QuickTime and a TIFF (or JPEG) decompressor are needed to see this picture

Problem

You open a presentation created on a Mac in your Windows version of PowerPoint and get a message similar to these:

QuickTime(TM) and a Photo - JPEG decompressor are needed to see this picture. 
QuickTime(TM) and a TIFF decompressor are needed to see this picture. 

The message may mention some other type of decompressor.

Solution

PPT2000: QuickTime PICT Placeholder Appears in Place of Graphic

The problem, in a nutshell, is that PowerPoint/Windows doesn't support QuickTime compression; installing QuickTime on the PC won't help.

One Mac PowerPoint newsgroup visitor reports that he fixed the problem by opening the presentation in PowerPoint 2008 on his Mac then saving it to PowerPoint 97-2003 format.

Another approach is to re-inserting the graphic into PowerPoint in PowerPoint for Macintosh.

• Open the original graphic in the program that created it
• Choose File, Save As
• Select No Compression in the save options (PowerPoint will compress the image when it imports it)
• Save as JPG or PNG or similar format that's compatible with both PC and Mac PPT versions.
• Switch to PowerPoint, choose Insert, Picture, From File and choose the newly saved picture.

Note: DO NOT drag and drop or copy/paste the graphic into PowerPoint. That's what probably caused the problem in the first place.

These instructions are very generic. The menu options for your graphics program will be different; you'll probably need to do some experimenting to find the right set of options.

If you come up with a good recipe you'd like to include here, post a message in the PowerPoint Newsgroup.

Another possible fix

This is still in the testing stage, but it's worth a try (on a COPY of your presentation, please!).
This exports each picture in your presentation to a PNG file, deletes the picture, then reimports the PNG in its place.

Notes:

• You'll need to change the path to suit your OS and system and optionally try different enlargement factors. See the notes under "EDIT THE FOLLOWING" below.
• The higher the enlargement factor, the higher the resolution of the exported/re-imported images (and the larger your PPT file). You'll want to experiment a bit to learn what works best for your needs.
• It doesn't delete the "temp" images it creates; you can have a look at them if you like or delete them manually.
• You can run this several times on the same presentation if you wish; it will only export/re-import a given picture one time.

Sub PNG_Me()
' Exports pictures to PNG, reimports them

  Dim sPath As String
  Dim dEnlargementFactor

  ' EDIT THE FOLLOWING:
  ' Name of folder for temp files
  ' It should always end with a path separator character:
  ' \ for PC, : (colon) for Mac
  ' The folder must already exist
sPath = "Macintosh HD:temp:"

  ' We enlarge the images before exporting them
  ' The higher the enlargement factor, the higher the resolution of the converted file
  ' This also serves to "optimize" your file sizes somewhat
  dEnlargementFactor = 2

  ' =========== NO USER-SERVICEABLE PARTS PAST THIS POINT
  Dim oOriginalPic As Shape
  Dim oNewPic As Shape
  Dim oSl As Slide
  Dim oSh As Shape
  Dim dLeft As Double
  Dim dTop As Double
  Dim dheight As Double
  Dim dwidth As Double
  Dim sImageName As String

  For Each oSl In ActivePresentation.Slides
    For Each oSh In oSl.Shapes
        ' Touch only pictures
        If oSh.Type = msoPicture Then
            ' Touch only pictures that haven't yet been touched
            If Len(oSh.Tags("PINGED")) = 0 Then
                With oSh
                    sImageName = sPath & "Slide" & CStr(oSl.SlideID) & "_" & oSh.Name & ".PNG"
                    ' memorize size/position
                    dTop = .Top
                    dwidth = .width
                    dheight = .height
                    dLeft = .Left
                    ' Enlarge, then export to PNG; lock aspect ratio first
                    oSh.LockAspectRatio = msoTrue
                    oSh.height = oSh.height * dEnlargementFactor
                    oSh.Export sImageName, ppShapeFormatPNG
                    ' and delete the shape
                    .Delete
                End With
                ' import saved picture
                Set oNewPic = oSl.Shapes.AddPicture(sImageName, msoFalse, msoTrue, dLeft, dTop, dwidth, dheight)
                Call oNewPic.Tags.Add("PINGED", "PONGED")
            End If
        End If
    Next
  Next

End Sub

See How do I use VBA code in PowerPoint? to learn how to use this example code.

---